Datei:Ballon2011 temperatur.png

reset
set title "Ballon Mission CCC Camp 2011"
set xlabel "Zeit nach Start (jumper) [min]"
set grid
set datafile separator ","
set terminal png small size 800,600
set output 'mission.png'
temperatur(x)  = (x*5)/10.240 - 273.15 + 3;
spannung(x)    = (x * 4.9 * 5.0)/1024;
druck(x)       = (x/1024.0 + 0.095)/0.009;
p0             =  100.72*exp(184.7/7990);
#hoehe_druck(x) = (log(p0/druck(x))*7990)/1000; # Barometrische höhenformel ohne Tempereratur.
#hoehe_druck_int(x) = (288.15/0.0065)*(1 - (druck(x)/101.325)**(1/5.255))/1000; # international
hoehe_druck_int(x) = (298.15/0.0065)*(1 - (druck(x)/p0)**(1/5.255))/1000; # am Wetter angepasst (gps)
plot 'datenlogger_csv.txt' using ($1/60):(temperatur($2)) w st t "Innentemperatur [°C]", \
                        '' using ($1/60):(temperatur($3)) w st t "Akku Temperatur [°C]", \
                        '' using ($1/60):(temperatur($4)) w st t "Aussentemperatur [°C]", \
                        '' using ($1/60):(druck($5)) w st t "Luftdruck [kPa]" , \
                        '' using ($1/60):(spannung($6)) w st t "Spannung [V]", \
                        '' using ($1/60):(hoehe_druck_int($5)) w st t "Höhe aus Luftdruck [km]"